server|存储过程|数据|数据库在我们编写用户身份验证程序中，很容易用ASP调用SQL语句来检索数据表中是否有条件相符的记录，然后再用ASP进行相关处理。
条条道路通罗马！当然，我们也可以用SQL SERVER数据库的存储过程来轻松实现这个功能。虽然相对而言较复杂，但其效率的提升是很明显的，因为存储过程是在数据库中已经编译好的一段程序，我们只需用ASP将其所用的各种参数正确传递就行了。
本文也主要是想通过一个简单的事例，向大家介绍一下如何在ASP中调用带参数的存储过程。希望大家能从中得到更多的启迪。
第一步，建立数据表userinfo
id int(4) not null,
fullname varchar(50) not null,
password varchar(20) not null,
nikename varchar(50) not null
第二步，建立存储过程usercheck
CREATE procedure usercheck
infullname varchar(50),
inpassword varchar(50),
outcheck char(3) OUTPUT
as
if exists(select * from userinfo where fullname=infullname and password=inpassword)
select outcheck='yes'
else
select outcheck='no'
注：这里建立了一个带三个参数的存储过程，第一个参数infullname，这是个输入参数，（用户名）；第二个参数inpassword，也是个输入参数，（密码）；第三个参数outcheck，这是个输出参数，（是否存在此用户），当定义输出参数时在数据类型后必须加上"OUTPUT"，字样。
然后，我们带上前两个输入参数在SQL语句中检索是否存在符合条件的用户，如果存在，输出参数的值为"yes",否则为"no"。
第三步，编写ASP程序，调用存储过程
<%
'表单提交标志
if request("ok")=1 then
'建立数据库连接
Set Comm=Server.CreateObject("ADODB.Command")
Comm.ActiveConnection="DSN=localserver;UID=sa;PWD=;Database=chaiwei"
'以comm对象建立存储过程连接,4代表连接类型为存储过程
Comm.CommandText="usercheck"
Comm.CommandType=4
'以p1为名称建立comm对象的parameter方法。将第一个参数fullname追加到p1集合中
'fullname 调用的第一个参数的名称
'200 参数类型 varchar型
'1 参数流向 输入，输入为1,输出为2
'50 参数的长度 50
'request("fullname") 赋参数出始值
Set p1=Comm.CreateParameter("fullname",200,1,50,request("fullname"))
Comm.Parameters.Append p1
'以p1为名称建立comm对象的parameter方法。将第二个参数password追加到p1集合中
'具体同上
Set p1=Comm.CreateParameter("password",200,1,20,request("password"))
Comm.Parameters.Append p1
'以p1为名称建立comm对象的parameter方法。将第三个参数check追加到p1集合中
'129 参数类型 char型
'2 参数流向 输出
'3 参数长度 3
Set p1=Comm.CreateParameter("check",129,2,3)
Comm.Parameters.Append p1
'运行存储过程
Comm.Execute
'提出结果，进行处理
if comm("check")="yes" then
response.write "欢迎进入系统！ 用户名：" & comm("fullname") & " 密码：" & comm("password")
else
response.write "对不起，您尚未注册！"
end if
'释放连接
Set Comm=nothing
else
'表单部份
%>
<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=gb2312">
<meta name="GENERATOR" content="Microsoft FrontPage 4.0">
<meta name="ProgId" content="FrontPage.Editor.Document">
<title>New Page 1</title>
</head>
<body>
<form method="POST" action="check.asp">
<p><input type="text" name="fullname" size="20">
<input type="password" name="password" size="20"></p>
<p><input type="submit" value="提交" name="B1"></p>
<input type="hidden" name="ok" value="1">
</form>
</body>
</html>
<%
end if
%>
调用SQL SERVER数据库存储过程实现ASP用户身份验证
80酷酷网 80kuku.com
